***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Feb 14, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt SBA330AH-AU A K 
.param
+vc0 = 1.293e-1
+vc1 = 1.042e-1
+vc2 = 1.064e-2
+tc1 = 8.413e-2
+tc2 = 3.419e-2
gdiode K A value={(vc0+vc1*v(K,A)+vc2*v(K,A)*v(K,A))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d1 A K diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3   
+ is = 6.576e-6
+  n = 1.055
+ rs = 1.864e-2
+ikf = 2.4
+bv = 33
***** capacitance parameter ***
+cjo = 1.904e-9
+  m = 1.098e-0
+ vj = 4.365e-1
+ fc = 0.5  
***** temperature coefficient ***
+tnom = 25                     
+  eg = 5.251e-1
+ xti = 3 
+trs1 = 3.822e-3
+trs2 = 6.488e-6
+tikf = -1e-3
.ends SBA330AH-AU
*$
